Your first reproducible simulation

Your first goal is not to memorize APDL: it is to open MAPDL with confidence, run a complete simulation and know where to look if something goes wrong. We will build a simple cantilever beam and walk together the workflow from Product Launcher to the result contour plots.

Objectives

At the end of M00 you will be able to demonstrate

• Configure Working Directory and Job Name in Product Launcher.
• Identifies Command Input, Output Window, Command Window, viewport, processor and active attributes.
• Run a file .mac via /INPUT.
• You recognize the flow /PREP7 → /SOLU → /POST1the existence of the /POST26 the function of FINISH.
• Explain what each block of the script represents and what evidence it produces.
• You find relevant errors and warnings in the file .out.
• Deformed checks, direction, order of magnitude and proportionality with the load.

Prerequisites

• Basic notions of finite element analysis.
• ANSYS Mechanical APDL available; screenshots may vary slightly between versions.
• A local folder where you have read and write permissions.
• No previous experience is required.

How to use this lesson

Recommendation: Get a visible result first. Then go back to the script and understand each block. Hands-on experience turns the commands from an abstract list into a working process.

Session map

Until the first /INPUT, the lesson follows five numbered steps. You start by the first; each leaves the session in a testable state before moving on to the next.

Step 1 — Prepare the working folder

Create a dedicated folder, for example:

C:\Proyectos_APDL\M00

Avoid working directly in Downloads, a temporary folder, or an unpermitted location. MAPDL will generate several files and all must be together to be able to reconstruct what happened.

Download 00_session_template.mac and save it in that folder.

Step 2 — Open MAPDL from Product Launcher

Open ANSYS Product Launcher and go into the tab File Management. The essential fields are:

1. Working Directory: folder from which MAPDL will read and write files to.
2. Job Name: initial prefix of the job and of several generated files.
3. Run: log in with that setting.

1 Working Directory

2 Job Name

3 Run

Step 3 — Become familiar with the MAPDL interface

Before running, take a minute to locate the main window and the Output Window:

Main window

Five zones you'll use in almost every session:

1. Command Input: top box where you can write an instruction.
2. Main Menu: side tree with preprocessing, solution and postprocessing.
3. viewport graphic area where geometry, mesh and results will appear.
4. active processor in the bottom bar you will initially see BEGIN.
5. Active Attributes: mat, type, real, csys and secnum.

1 2 3 4 5

Output Window

When you open MAPDL, a separate window entitled Mechanical APDL … Output. It is not where you type commands; it is the live log of everything the program writes — version and working directory, job name, graphical interface startup, command echo, solver progress, warnings, and errors.

On Windows, interactive MAPDL displays that output in the Output Window, but does not write it to disk by default. To retain the log in a file, redirect it with /OUTPUT,Fname,Ext or use the toolbar menu Utility Menu → File → Switch Output to → File). In M00 it is not necessary to do it by hand: /OUTPUT,m00_session,out is already included in the template, immediately after /FILNAME.

The output file name must not match the job prefix. Because /FILNAME sets m00_cantilever, and ANSYS reserves m00_cantilever.out for the job, the template writes the execution log to the alternative file m00_session.out.

While running, the Output Window remains the first place to spot an error; the .out file lets you review the same content afterward.

BEGIN does not mean “without context”

BEGIN is the initial level of MAPDL: the session has just opened and you have not yet entered no specific processor. A processor is the mode of work that determines what APDL commands accept MAPDL at that time. Think of it as a phase of the analysis: not every commands are valid in all phases.

The processors you'll use most often are four:

POST1 and POST26 are complementary postprocessors: you enter one or the other after solving, depending on whether you want to inspect a field in an instant or an evolution between sets. M00 template only uses POST1; /POST26 you'll see it in M07.

To enter, type the command in Command Input and press Enter (or include it in a .mac). To exit the current processor and return to BEGIN, use FINISH. The bottom bar - the point 4 from the list above - shows where you are at all times; when running the template you will see how it changes successively from BEGIN to PREP7, SOLUTION and POST1.

The Main Menu of point 2 reflects the same logic: its preprocessing, solution and post-processing open those processors. In this course we will enter by APDL commands, not by menus.

Active attributes: defining is not activating

MAPDL uses numbered tables. ET,1,... defines the element type 1 and MP,...,1,... defines the material 1. After TYPE,1 and MAT,1 turn them into active attributes for the elements to be created.

Step 4 — Undock the Command Window

Don't confuse the Output Window with the Command Window. The Output records all the session flow; the Command Window is optional and displays the interactive command dialog, immediate messages and responses. It can be integrated or decoupled depending on version and configuration.

Use it as an interactive execution monitor, not as a substitute for on-disk recording. You don't need read each line in real time or set up redirection by hand - template includes /OUTPUT,m00_session,out pre-assigned and, in the end, a /OUTPUT without arguments that returns the output to the Output Window in real time.

Step 5 — Run the template

Write in Command Input:

/INPUT,00_session_template,mac

The instruction has three parts:

• /INPUT: prompts MAPDL to read commands from a file.
• 00_session_template: name without extension.
• mac.extension

If the file is in the Working Directory, you do not need to write the full path. During the execution you will see the geometry, the mesh and finally the contours appear.

Physical model

The template represents a cantilever beam with the following characteristics:

The end x=0 is embedded and the load acts on the nodes of x=1 m. The geometry is deliberately simple: at M00 we want to learn how to execute and read the analysis, not solving a complicated geometry.

Script anatomy

Opens the file in an editor. It is divided into five blocks:

1. Initialize Database
2. Define and mesh the model.
3. Apply underlayment and load.
4. Overcome
5. Read and represent results.

Block 1 — Initialize the session

/CLEAR,START
/FILNAME,m00_cantilever,1
/OUTPUT,m00_session,out
/TITLE,M00 - Cantilever beam
/UNITS,SI

Block 2 — Enter PREP7 and define attributes

/PREP7
ET,1,SOLID185
MP,EX,1,210E9
MP,PRXY,1,0.30
TYPE,1
MAT,1

• /PREP7 enters the preprocessor: geometry, elements, materials, mesh and conditions.
• ET,1,SOLID185 defines the element type 1 as a structural solid.
• MP,EX,1,210E9 defines the elastic modulus of the 1 material.
• MP,PRXY,1,0.30 defines its Poisson coefficient.
• TYPE,1 and MAT,1 activate those boards before meshing.

M03 will justify in detail the choice of the element and compare idealizations. In M00 just recognize which element and material must be defined and active before generating elements.

Block 3 — Create geometry and mesh

BLOCK,0,1.0,0,0.10,0,0.05
ESIZE,0.025
VMESH,ALL

• BLOCK creates a rectangular volume with X, Y and Z boundaries.
• ESIZE proposes an overall element size.
• VMESH,ALL mesh all selected volumes.

A visible mesh does not imply a converged mesh. M04 will study sensitivity and quality. Here we only need reasonable discretization to complete the flow.

Block 4 — Select and constrain

NSEL,S,LOC,X,0
D,ALL,ALL,0
ALLSEL,ALL

NSEL,S,LOC,X,0 replaces the current selection with the nodes located in x=0. D,ALL,ALL,0 restricts all of its available degrees of freedom. Finally, ALLSEL,ALL retrieves all entities.

Block 5 — Distribute the total force

NSEL,S,LOC,X,1.0
*GET,n_tip,NODE,0,COUNT
F,ALL,FY,-1000/n_tip
ALLSEL,ALL

The end nodes are selected first. *GET count how many there are and save the result en n_tip. The strength of each node is -1000/n_tip, so the sum remains equal to − 1000N even if you change the mesh.

This idea is important: the input value represents a total force, not a force that must be repeated in full at each node.

Block 6 — Exit PREP7 and Solve

FINISH

/SOLU
ANTYPE,STATIC
SOLVE
FINISH

• FINISH exits the current processor and returns to BEGIN.
• /SOLU goes into Solution.
• ANTYPE,STATIC declares a static analysis.
• SOLVE requests the solution of the current load step.
• The second FINISH closes the solution stage.

That SOLVE finish only proves that the solver got an answer. We still have to check if it correctly represents the physical problem.

Block 7 — Enter POST1

/POST1
SET,LAST
PLNSOL,U,SUM
PLNSOL,S,EQV
FINISH

/OUTPUT

• /POST1 opens the general postprocessor.
• SET,LAST read the latest set of results available.
• PLNSOL,U,SUM represents the magnitude of the displacement.
• PLNSOL,S,EQV represents the equivalent stress.
• /OUTPUT with no arguments returns live text output to the Output Window.

Each plot replaces the previous one in the viewport. At the end you will see the equivalent stress. You can rerun PLNSOL,U,SUM manually to restore the displacement contour.

What files should you find

How to read the .out file

The template includes /OUTPUT,m00_session,out immediately after /FILNAME. From there, what MAPDL writes in the Output Window also remains in m00_session.out until the final /OUTPUT, which returns output to the live window. Open it as text and search, in this order:

1. ERROR or FATAL: may invalidate or stop the execution.
2. WARNING: Requires interpretation; not all warnings are of equal severity.
3. The solution section: confirms that it was reached SOLVE.
4. The end of the file: check that the script reached POST1.

Do not change solver options at random at the first message. Identify the stage first, the entity and instruction related to the symptom.

Independent physical check

For a rectangular beam:

I = B·H³/12
|uy_tip| = P·L³/(3·E·I)

With the model values:

I = 4.1667E-6 m⁴
|uy_tip| ≈ 3.81E-4 m = 0.381 mm

The 3D solid model does not have to match Euler–Bernoulli exactly. In this first session we look for the order of magnitude. M04 and M07 will turn this comparison into a formal study.

Verifiable challenge — The linearity test

Before modifying anything, predict what will happen when the load is duplicated:

F,ALL,FY,-2000/n_tip

1. Run the case of −1000 N and record the vertical displacement of the end.
2. Only change the total force to −2000 N.
3. Run again with the same geometry, material and mesh.
4. Compute uy_2000/uy_1000.

Common mistakes

Self-assessment

Evidence of learning

• Working Directory 00_session_template.mac, m00_session.out and m00_cantilever.rst.
• A viewport screenshot showing the deformed shape or displacement contour.
• An excerpt from m00_session.out confirming that the solution completed.
• Table with load, displacement and ratio between the two cases.
• A brief explanation of why the observed ratio demonstrates linear behavior.

Validation checklist

• I created a dedicated folder with write permissions.
• I set up Working Directory and Job Name on Product Launcher.
• I identified Command Input, Output Window, Command Window, viewport, processor and attributes.
• Execute the template using /INPUT.
• I found m00_session.out and m00_cantilever.rst.
• The deformation and direction of travel are physically reasonable.
• I compared the order of magnitude to 0.381 mm.
• I completed the challenge with a ratio between 1.99 and 2.01.
• I can explain the function of each block of the script without memorizing all its arguments.